Rules for integrands involving error functions

1.  ∫((Erf[a+b x])^n)dx

1:  ∫Erf[a+b x]dx

Reference: G&R 5.41

Derivation: Integration by parts

Basis: (∂_x)Erf[a+b x]==((2 b)/((Sqrt[π]) (e^(((a+b x))^2))))

Rule:

∫Erf[a+b x]dx  ⟶  (((a+b x) Erf[a+b x])/b)-(2/(Sqrt[π]))∫((a+b x)/(e^(((a+b x))^2)))dx  ⟶  (((a+b x) Erf[a+b x])/b)+(1/(b (Sqrt[π]) (e^(((a+b x))^2))))

Program code:

Int[Erf[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*Erf[a+b*x]/b + 1/(b*Sqrt[Pi]*E^(a+b*x)^2) /;
FreeQ[{a,b},x]

Int[Erfc[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*Erfc[a+b*x]/b - 1/(b*Sqrt[Pi]*E^(a+b*x)^2) /;
FreeQ[{a,b},x]

Int[Erfi[a_.+b_.*x_],x_Symbol] :=
  (a+b*x)*Erfi[a+b*x]/b - E^(a+b*x)^2/(b*Sqrt[Pi]) /;
FreeQ[{a,b},x]

2:  ∫((Erf[a+b x])^2)dx

Derivation: Integration by parts

Basis: (∂_x)((Erf[a+b x])^2)==((4 b Erf[a+b x])/((Sqrt[π]) (e^(((a+b x))^2))))

Rule:

∫((Erf[a+b x])^2)dx  ⟶  (((a+b x) ((Erf[a+b x])^2))/b)-(4/(Sqrt[π]))∫(((a+b x) Erf[a+b x])/(e^(((a+b x))^2)))dx

Program code:

Int[Erf[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*Erf[a+b*x]^2/b -
  4/Sqrt[Pi]*Int[(a+b*x)*Erf[a+b*x]/E^(a+b*x)^2,x] /;
FreeQ[{a,b},x]

Int[Erfc[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*Erfc[a+b*x]^2/b +
  4/Sqrt[Pi]*Int[(a+b*x)*Erfc[a+b*x]/E^(a+b*x)^2,x] /;
FreeQ[{a,b},x]

Int[Erfi[a_.+b_.*x_]^2,x_Symbol] :=
  (a+b*x)*Erfi[a+b*x]^2/b -
  4/Sqrt[Pi]*Int[(a+b*x)*E^(a+b*x)^2*Erfi[a+b*x],x] /;
FreeQ[{a,b},x]

U:  ∫((Erf[a+b x])^n)dx  when  n≠1 ∧ n≠2

Rule: If  n≠1 ∧ n≠2, then

∫((Erf[a+b x])^n)dx  ⟶  ∫((Erf[a+b x])^n)dx

Program code:

Int[Erf[a_.+b_.*x_]^n_,x_Symbol] :=
  Unintegrable[Erf[a+b*x]^n,x] /;
FreeQ[{a,b,n},x] && NeQ[n,1] && NeQ[n,2]

Int[Erfc[a_.+b_.*x_]^n_,x_Symbol] :=
  Unintegrable[Erfc[a+b*x]^n,x] /;
FreeQ[{a,b,n},x] && NeQ[n,1] && NeQ[n,2]

Int[Erfi[a_.+b_.*x_]^n_,x_Symbol] :=
  Unintegrable[Erfi[a+b*x]^n,x] /;
FreeQ[{a,b,n},x] && NeQ[n,1] && NeQ[n,2]

2.  ∫(((c+d x))^m) ((Erf[a+b x])^n)dx

1.  ∫(((c+d x))^m) Erf[a+b x]dx

1:  ∫((Erf[b x])/x)dx

Basis: Erfc[z]==1-Erf[z]

Rule:

∫((Erf[b x])/x)dx  ⟶  ((2 b x)/(Sqrt[π]))HypergeometricPFQ[{(1/2),(1/2)},{(3/2),(3/2)},-(b^2) (x^2)]

Program code:

Int[Erf[b_.*x_]/x_,x_Symbol] :=
  2*b*x/Sqrt[Pi]*HypergeometricPFQ[{1/2,1/2},{3/2,3/2},-b^2*x^2] /;
FreeQ[b,x]

Int[Erfc[b_.*x_]/x_,x_Symbol] :=
  Log[x] - Int[Erf[b*x]/x,x] /;
FreeQ[b,x]

Int[Erfi[b_.*x_]/x_,x_Symbol] :=
  2*b*x/Sqrt[Pi]*HypergeometricPFQ[{1/2,1/2},{3/2,3/2},b^2*x^2] /;
FreeQ[b,x]

2:  ∫(((c+d x))^m)Erf[a+b x]dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)Erf[a+b x]==((2 b)/((Sqrt[π]) (e^(((a+b x))^2))))

Rule: If  m≠-1, then

∫(((c+d x))^m)Erf[a+b x]dx  ⟶  (((((c+d x))^(m+1)) Erf[a+b x])/(d (m+1)))-((2 b)/((Sqrt[π]) d (m+1)))∫((((c+d x))^(m+1))/(e^(((a+b x))^2)))dx

Program code:

Int[(c_.+d_.*x_)^m_.*Erf[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*Erf[a+b*x]/(d*(m+1)) -
  2*b/(Sqrt[Pi]*d*(m+1))*Int[(c+d*x)^(m+1)/E^(a+b*x)^2,x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

Int[(c_.+d_.*x_)^m_.*Erfc[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*Erfc[a+b*x]/(d*(m+1)) +
  2*b/(Sqrt[Pi]*d*(m+1))*Int[(c+d*x)^(m+1)/E^(a+b*x)^2,x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

Int[(c_.+d_.*x_)^m_.*Erfi[a_.+b_.*x_],x_Symbol] :=
  (c+d*x)^(m+1)*Erfi[a+b*x]/(d*(m+1)) -
  2*b/(Sqrt[Pi]*d*(m+1))*Int[(c+d*x)^(m+1)*E^(a+b*x)^2,x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

2.  ∫(((c+d x))^m) ((Erf[a+b x])^2)dx

1:  ∫(x^m) ((Erf[b x])^2)dx  when  m∈(SuperPlus[ℤ]) ∨ ((m+1)/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)((Erf[b x])^2)==((4 b Erf[b x])/((Sqrt[π]) (e^((b^2) (x^2)))))

Rule: If  m∈(SuperPlus[ℤ]) ∨ ((m+1)/2)∈(SuperMinus[ℤ]), then

∫(x^m) ((Erf[b x])^2)dx  ⟶  (((x^(m+1)) ((Erf[b x])^2))/(m+1))-((4 b)/((Sqrt[π]) (m+1)))∫(((x^(m+1)) Erf[b x])/(e^((b^2) (x^2))))dx

Program code:

Int[x_^m_.*Erf[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*Erf[b*x]^2/(m+1) -
  4*b/(Sqrt[Pi]*(m+1))*Int[x^(m+1)*E^(-b^2*x^2)*Erf[b*x],x] /;
FreeQ[b,x] && (IGtQ[m,0] || ILtQ[(m+1)/2,0])

Int[x_^m_.*Erfc[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*Erfc[b*x]^2/(m+1) +
  4*b/(Sqrt[Pi]*(m+1))*Int[x^(m+1)*E^(-b^2*x^2)*Erfc[b*x],x] /;
FreeQ[b,x] && (IGtQ[m,0] || ILtQ[(m+1)/2,0])

Int[x_^m_.*Erfi[b_.*x_]^2,x_Symbol] :=
  x^(m+1)*Erfi[b*x]^2/(m+1) -
  4*b/(Sqrt[Pi]*(m+1))*Int[x^(m+1)*E^(b^2*x^2)*Erfi[b*x],x] /;
FreeQ[b,x] && (IGtQ[m,0] || ILtQ[(m+1)/2,0])

2:  ∫(((c+d x))^m) ((Erf[a+b x])^2)dx  when  m∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Rule: If  m∈(SuperPlus[ℤ]), then

∫(((c+d x))^m) ((Erf[a+b x])^2)dx  ⟶  (1/(b^(m+1))) Subst[∫((Erf[x])^2) ExpandIntegrand[(((b c-a d+d x))^m),x]dx,x,a+b x]

Program code:

Int[(c_.+d_.*x_)^m_.*Erf[a_+b_.*x_]^2,x_Symbol] :=
  1/b^(m+1)*Subst[Int[ExpandIntegrand[Erf[x]^2,(b*c-a*d+d*x)^m,x],x],x,a+b*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

Int[(c_.+d_.*x_)^m_.*Erfc[a_+b_.*x_]^2,x_Symbol] :=
  1/b^(m+1)*Subst[Int[ExpandIntegrand[Erfc[x]^2,(b*c-a*d+d*x)^m,x],x],x,a+b*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

Int[(c_.+d_.*x_)^m_.*Erfi[a_+b_.*x_]^2,x_Symbol] :=
  1/b^(m+1)*Subst[Int[ExpandIntegrand[Erfi[x]^2,(b*c-a*d+d*x)^m,x],x],x,a+b*x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,0]

U:  ∫(((c+d x))^m) ((Erf[a+b x])^n)dx

Rule:

∫(((c+d x))^m) ((Erf[a+b x])^n)dx  ⟶  ∫(((c+d x))^m) ((Erf[a+b x])^n)dx

Program code:

Int[(c_.+d_.*x_)^m_.*Erf[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(c+d*x)^m*Erf[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,m,n},x]

Int[(c_.+d_.*x_)^m_.*Erfc[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(c+d*x)^m*Erfc[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,m,n},x]

Int[(c_.+d_.*x_)^m_.*Erfi[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(c+d*x)^m*Erfi[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,m,n},x]

3.  ∫(e^(c+d (x^2))) ((Erf[a+b x])^n)dx

1.  ∫(e^(c+d (x^2))) ((Erf[b x])^n)dx  when  (d^2)==(b^4)

1:  ∫(e^(c+d (x^2))) ((Erf[b x])^n)dx  when  d==-(b^2)

Derivation: Integration by substitution

Basis: If  d==-(b^2), then (e^(c+d (x^2))) F[Erf[b x]]==(((e^c) (Sqrt[π]))/(2 b)) Subst[F[x],x,Erf[b x]] (∂_x)Erf[b x]

Rule: If  d==-(b^2), then

∫(e^(c+d (x^2))) ((Erf[b x])^n)dx  ⟶  (((e^c) (Sqrt[π]))/(2 b)) Subst[∫(x^n)dx,x,Erf[b x]]

Program code:

Int[E^(c_.+d_.*x_^2)*Erf[b_.*x_]^n_.,x_Symbol] :=
  E^c*Sqrt[Pi]/(2*b)*Subst[Int[x^n,x],x,Erf[b*x]] /;
FreeQ[{b,c,d,n},x] && EqQ[d,-b^2]

Int[E^(c_.+d_.*x_^2)*Erfc[b_.*x_]^n_.,x_Symbol] :=
  -E^c*Sqrt[Pi]/(2*b)*Subst[Int[x^n,x],x,Erfc[b*x]] /;
FreeQ[{b,c,d,n},x] && EqQ[d,-b^2]

Int[E^(c_.+d_.*x_^2)*Erfi[b_.*x_]^n_.,x_Symbol] :=
  E^c*Sqrt[Pi]/(2*b)*Subst[Int[x^n,x],x,Erfi[b*x]] /;
FreeQ[{b,c,d,n},x] && EqQ[d,b^2]

2:  ∫(e^(c+d (x^2))) Erf[b x]dx  when  d==(b^2)

Basis: Erfc[z]==1-Erf[z]

Rule: If  d==(b^2), then

∫(e^(c+d (x^2))) Erf[b x]dx  ⟶  ((b (e^c) (x^2))/(Sqrt[π])) HypergeometricPFQ[{1,1},{(3/2),2},(b^2) (x^2)]

Program code:

Int[E^(c_.+d_.*x_^2)*Erf[b_.*x_],x_Symbol] :=
  b*E^c*x^2/Sqrt[Pi]*HypergeometricPFQ[{1,1},{3/2,2},b^2*x^2] /;
FreeQ[{b,c,d},x] && EqQ[d,b^2]

Int[E^(c_.+d_.*x_^2)*Erfc[b_.*x_],x_Symbol] :=
  Int[E^(c+d*x^2),x] - Int[E^(c+d*x^2)*Erf[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d,b^2]

Int[E^(c_.+d_.*x_^2)*Erfi[b_.*x_],x_Symbol] :=
  b*E^c*x^2/Sqrt[Pi]*HypergeometricPFQ[{1,1},{3/2,2},-b^2*x^2] /;
FreeQ[{b,c,d},x] && EqQ[d,-b^2]

U:  ∫(e^(c+d (x^2))) ((Erf[a+b x])^n)dx

Rule:

∫(e^(c+d (x^2))) ((Erf[a+b x])^n)dx  ⟶  ∫(e^(c+d (x^2))) ((Erf[a+b x])^n)dx

Program code:

Int[E^(c_.+d_.*x_^2)*Erf[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[E^(c+d*x^2)*Erf[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

Int[E^(c_.+d_.*x_^2)*Erfc[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[E^(c+d*x^2)*Erfc[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

Int[E^(c_.+d_.*x_^2)*Erfi[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[E^(c+d*x^2)*Erfi[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,n},x]

4.  ∫(((e x))^m) (e^(c+d (x^2))) ((Erf[a+b x])^n)dx

1.  ∫(x^m) (e^(c+d (x^2))) Erf[a+b x]dx  when  m∈ℤ

1.  ∫(x^m)(e^(c+d (x^2))) Erf[a+b x]dx  when  m∈(SuperPlus[ℤ])

1:  ∫x (e^(c+d (x^2)))Erf[a+b x]dx

Derivation: Integration by parts

Basis: ∫x (e^(c+d (x^2)))dx==(1/(2 d))(e^(c+d (x^2)))

Basis: (∂_x)Erf[a+b x]==((2 b)/(Sqrt[π]))(e^(-(a^2)-2 a b x-(b^2) (x^2)))

Rule:

∫x (e^(c+d (x^2)))Erf[a+b x]dx  ⟶  (((e^(c+d (x^2)))Erf[a+b x])/(2 d))-(b/(d (Sqrt[π])))∫(e^(-(a^2)+c-2 a b x-((b^2)-d) (x^2)))dx

Program code:

Int[x_*E^(c_.+d_.*x_^2)*Erf[a_.+b_.*x_],x_Symbol] :=
  E^(c+d*x^2)*Erf[a+b*x]/(2*d) - 
  b/(d*Sqrt[Pi])*Int[E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] /;
FreeQ[{a,b,c,d},x]

Int[x_*E^(c_.+d_.*x_^2)*Erfc[a_.+b_.*x_],x_Symbol] :=
  E^(c+d*x^2)*Erfc[a+b*x]/(2*d) + 
  b/(d*Sqrt[Pi])*Int[E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] /;
FreeQ[{a,b,c,d},x]

Int[x_*E^(c_.+d_.*x_^2)*Erfi[a_.+b_.*x_],x_Symbol] :=
  E^(c+d*x^2)*Erfi[a+b*x]/(2*d) - 
  b/(d*Sqrt[Pi])*Int[E^(a^2+c+2*a*b*x+(b^2+d)*x^2),x] /;
FreeQ[{a,b,c,d},x]

2:  ∫(x^m) (e^(c+d (x^2)))Erf[a+b x]dx  when  m-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: ∫x (e^(c+d (x^2)))dx==(1/(2 d))(e^(c+d (x^2)))

Basis: (∂_x)((x^(m-1)) Erf[a+b x])==((2 b)/(Sqrt[π]))(x^(m-1))(e^(-(a^2)-2 a b x-(b^2) (x^2)))+(m-1) (x^(m-2)) Erf[a+b x]

Rule: If  m-1∈(SuperPlus[ℤ]), then

∫(x^m) (e^(c+d (x^2)))Erf[a+b x]dx  ⟶  
(((x^(m-1))(e^(c+d (x^2)))Erf[a+b x])/(2 d))-(b/(d (Sqrt[π])))∫(x^(m-1))(e^(-(a^2)+c-2 a b x-((b^2)-d) (x^2)))dx-((m-1)/(2 d))∫(x^(m-2))(e^(c+d (x^2)))Erf[a+b x]dx

Program code:

Int[x_^m_*E^(c_.+d_.*x_^2)*Erf[a_.+b_.*x_],x_Symbol] :=
  x^(m-1)*E^(c+d*x^2)*Erf[a+b*x]/(2*d) - 
  b/(d*Sqrt[Pi])*Int[x^(m-1)*E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] - 
  (m-1)/(2*d)*Int[x^(m-2)*E^(c+d*x^2)*Erf[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,1]

Int[x_^m_*E^(c_.+d_.*x_^2)*Erfc[a_.+b_.*x_],x_Symbol] :=
  x^(m-1)*E^(c+d*x^2)*Erfc[a+b*x]/(2*d) + 
  b/(d*Sqrt[Pi])*Int[x^(m-1)*E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] - 
  (m-1)/(2*d)*Int[x^(m-2)*E^(c+d*x^2)*Erfc[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,1]

Int[x_^m_*E^(c_.+d_.*x_^2)*Erfi[a_.+b_.*x_],x_Symbol] :=
  x^(m-1)*E^(c+d*x^2)*Erfi[a+b*x]/(2*d) - 
  b/(d*Sqrt[Pi])*Int[x^(m-1)*E^(a^2+c+2*a*b*x+(b^2+d)*x^2),x] - 
  (m-1)/(2*d)*Int[x^(m-2)*E^(c+d*x^2)*Erfi[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && IGtQ[m,1]

2.  ∫(x^m)(e^(c+d (x^2))) Erf[a+b x]dx  when  m∈(SuperMinus[ℤ])

1:  ∫(((e^(c+d (x^2))) Erf[b x])/x)dx  when  d==(b^2)

Basis: Erfc[z]==1-Erf[z]

Rule: If  d==(b^2), then

∫(((e^(c+d (x^2))) Erf[b x])/x)dx  ⟶  ((2 b (e^c) x)/(Sqrt[π]))HypergeometricPFQ[{(1/2),1},{(3/2),(3/2)},(b^2) (x^2)]

Program code:

Int[E^(c_.+d_.*x_^2)*Erf[b_.*x_]/x_,x_Symbol] :=
  2*b*E^c*x/Sqrt[Pi]*HypergeometricPFQ[{1/2,1},{3/2,3/2},b^2*x^2] /;
FreeQ[{b,c,d},x] && EqQ[d,b^2]

Int[E^(c_.+d_.*x_^2)*Erfc[b_.*x_]/x_,x_Symbol] :=
  Int[E^(c+d*x^2)/x,x] - Int[E^(c+d*x^2)*Erf[b*x]/x,x] /;
FreeQ[{b,c,d},x] && EqQ[d,b^2]

Int[E^(c_.+d_.*x_^2)*Erfi[b_.*x_]/x_,x_Symbol] :=
  2*b*E^c*x/Sqrt[Pi]*HypergeometricPFQ[{1/2,1},{3/2,3/2},-b^2*x^2] /;
FreeQ[{b,c,d},x] && EqQ[d,-b^2]

2:  ∫(x^m)(e^(c+d (x^2)))Erf[a+b x]dx  when  m+1∈(SuperMinus[ℤ])

Derivation: Inverted integration by parts

Rule: If  m+1∈(SuperMinus[ℤ]), then

∫(x^m)(e^(c+d (x^2)))Erf[a+b x]dx  ⟶  
(((x^(m+1))(e^(c+d (x^2)))Erf[a+b x])/(m+1))-((2b)/((m+1)(Sqrt[π])))∫(x^(m+1))(e^(-(a^2)+c-2 a b x-((b^2)-d) (x^2)))dx-((2 d)/(m+1))∫(x^(m+2)) (e^(c+d (x^2)))Erf[a+b x]dx

Program code:

Int[x_^m_*E^(c_.+d_.*x_^2)*Erf[a_.+b_.*x_],x_Symbol] :=
  x^(m+1)*E^(c+d*x^2)*Erf[a+b*x]/(m+1) - 
  2*b/((m+1)*Sqrt[Pi])*Int[x^(m+1)*E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] - 
  2*d/(m+1)*Int[x^(m+2)*E^(c+d*x^2)*Erf[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[m,-1]

Int[x_^m_*E^(c_.+d_.*x_^2)*Erfc[a_.+b_.*x_],x_Symbol] :=
  x^(m+1)*E^(c+d*x^2)*Erfc[a+b*x]/(m+1) + 
  2*b/((m+1)*Sqrt[Pi])*Int[x^(m+1)*E^(-a^2+c-2*a*b*x-(b^2-d)*x^2),x] - 
  2*d/(m+1)*Int[x^(m+2)*E^(c+d*x^2)*Erfc[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[m,-1]

Int[x_^m_*E^(c_.+d_.*x_^2)*Erfi[a_.+b_.*x_],x_Symbol] :=
  x^(m+1)*E^(c+d*x^2)*Erfi[a+b*x]/(m+1) - 
  2*b/((m+1)*Sqrt[Pi])*Int[x^(m+1)*E^(a^2+c+2*a*b*x+(b^2+d)*x^2),x] - 
  2*d/(m+1)*Int[x^(m+2)*E^(c+d*x^2)*Erfi[a+b*x],x] /;
FreeQ[{a,b,c,d},x] && ILtQ[m,-1]

U:  ∫(((e x))^m) (e^(c+d (x^2))) ((Erf[a+b x])^n)dx

Rule:

∫(((e x))^m) (e^(c+d (x^2))) ((Erf[a+b x])^n)dx  ⟶  ∫(((e x))^m) (e^(c+d (x^2))) ((Erf[a+b x])^n)dx

Program code:

Int[(e_.*x_)^m_.*E^(c_.+d_.*x_^2)*Erf[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*E^(c+d*x^2)*Erf[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

Int[(e_.*x_)^m_.*E^(c_.+d_.*x_^2)*Erfc[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*E^(c+d*x^2)*Erfc[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

Int[(e_.*x_)^m_.*E^(c_.+d_.*x_^2)*Erfi[a_.+b_.*x_]^n_.,x_Symbol] :=
  Unintegrable[(e*x)^m*E^(c+d*x^2)*Erfi[a+b*x]^n,x] /;
FreeQ[{a,b,c,d,e,m,n},x]

5.  ∫u Erf[d (a+b Log[c (x^n)])]dx

1:  ∫Erf[d (a+b Log[c (x^n)])]dx

Derivation: Integration by parts

Basis: (∂_x)Erf[d (a+b Log[c (x^n)])]==((2 b d n)/((Sqrt[π]) x (e^(((d (a+b Log[c (x^n)])))^2))))

Rule:

∫Erf[d (a+b Log[c (x^n)])]dx  ⟶  x Erf[d (a+b Log[c (x^n)])]-((2 b d n)/(Sqrt[π])) ∫(1/(e^(((d (a+b Log[c (x^n)])))^2)))dx

Program code:

Int[Erf[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*Erf[d*(a+b*Log[c*x^n])] - 2*b*d*n/(Sqrt[Pi])*Int[1/E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,n},x]

Int[Erfc[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*Erfc[d*(a+b*Log[c*x^n])] + 2*b*d*n/(Sqrt[Pi])*Int[1/E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,n},x]

Int[Erfi[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  x*Erfi[d*(a+b*Log[c*x^n])] - 2*b*d*n/(Sqrt[Pi])*Int[E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,n},x]

2:  ∫((Erf[d (a+b Log[c (x^n)])])/x)dx

Derivation: Integration by substitution

Basis: ((F[Log[c (x^n)]])/x)==(1/n) Subst[F[x],x,Log[c (x^n)]] (∂_x)Log[c (x^n)]

Rule:

∫((Erf[d (a+b Log[c (x^n)])])/x)dx  ⟶  (1/n) Subst[Erf[d (a+b x)],x,Log[c (x^n)]]

Program code:

Int[F_[d_.*(a_.+b_.*Log[c_.*x_^n_.])]/x_,x_Symbol] :=
  1/n*Subst[F[d*(a+b*x)],x,Log[c*x^n]] /;
FreeQ[{a,b,c,d,n},x] && MemberQ[{Erf,Erfc,Erfi},F]

3:  ∫(((e x))^m) Erf[d (a+b Log[c (x^n)])]dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)Erf[d (a+b Log[c (x^n)])]==((2 b d n)/((Sqrt[π]) x (e^(((d (a+b Log[c (x^n)])))^2))))

Rule: If  m≠-1, then

∫(((e x))^m) Erf[d (a+b Log[c (x^n)])]dx  ⟶  (((((e x))^(m+1)) Erf[d (a+b Log[c (x^n)])])/(e (m+1)))-((2 b d n)/((Sqrt[π]) (m+1))) ∫((((e x))^m)/(e^(((d (a+b Log[c (x^n)])))^2)))dx

Program code:

Int[(e_.*x_)^m_.*Erf[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*Erf[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  2*b*d*n/(Sqrt[Pi]*(m+1))*Int[(e*x)^m/E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

Int[(e_.*x_)^m_.*Erfc[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*Erfc[d*(a+b*Log[c*x^n])]/(e*(m+1)) + 
  2*b*d*n/(Sqrt[Pi]*(m+1))*Int[(e*x)^m/E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

Int[(e_.*x_)^m_.*Erfi[d_.*(a_.+b_.*Log[c_.*x_^n_.])],x_Symbol] :=
  (e*x)^(m+1)*Erfi[d*(a+b*Log[c*x^n])]/(e*(m+1)) - 
  2*b*d*n/(Sqrt[Pi]*(m+1))*Int[(e*x)^m*E^(d*(a+b*Log[c*x^n]))^2,x] /;
FreeQ[{a,b,c,d,e,m,n},x] && NeQ[m,-1]

6:  ∫Sin[c+d (x^2)] Erf[b x]dx  when  (d^2)==-(b^4)

Derivation: Algebraic expansion

Basis: Sin[c+d (x^2)]==(1/2) i (e^(-i c-i d (x^2)))-(1/2) i (e^(i c+i d (x^2)))

Rule: If  (d^2)==-(b^4), then

∫Sin[c+d (x^2)] Erf[b x]dx  ⟶  (i/2) ∫(e^(-i c-i d (x^2))) Erf[b x]dx-(i/2) ∫(e^(i c+i d (x^2))) Erf[b x]dx

Program code:

Int[Sin[c_.+d_.*x_^2]*Erf[b_.*x_],x_Symbol] :=
  I/2*Int[E^(-I*c-I*d*x^2)*Erf[b*x],x] - I/2*Int[E^(I*c+I*d*x^2)*Erf[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

Int[Sin[c_.+d_.*x_^2]*Erfc[b_.*x_],x_Symbol] :=
  I/2*Int[E^(-I*c-I*d*x^2)*Erfc[b*x],x] - I/2*Int[E^(I*c+I*d*x^2)*Erfc[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

Int[Sin[c_.+d_.*x_^2]*Erfi[b_.*x_],x_Symbol] :=
  I/2*Int[E^(-I*c-I*d*x^2)*Erfi[b*x],x] - I/2*Int[E^(I*c+I*d*x^2)*Erfi[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

Int[Cos[c_.+d_.*x_^2]*Erf[b_.*x_],x_Symbol] :=
  1/2*Int[E^(-I*c-I*d*x^2)*Erf[b*x],x] + 1/2*Int[E^(I*c+I*d*x^2)*Erf[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

Int[Cos[c_.+d_.*x_^2]*Erfc[b_.*x_],x_Symbol] :=
  1/2*Int[E^(-I*c-I*d*x^2)*Erfc[b*x],x] + 1/2*Int[E^(I*c+I*d*x^2)*Erfc[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

Int[Cos[c_.+d_.*x_^2]*Erfi[b_.*x_],x_Symbol] :=
  1/2*Int[E^(-I*c-I*d*x^2)*Erfi[b*x],x] + 1/2*Int[E^(I*c+I*d*x^2)*Erfi[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,-b^4]

7:  ∫Sinh[c+d x] Erf[b x]dx  when  (d^2)==(b^4)

Derivation: Algebraic expansion

Basis: Sinh[c+d (x^2)]==(1/2) (e^(c+d (x^2)))-(1/2) (e^(-c-d (x^2)))

Rule: If  (d^2)==(b^4), then

∫Sinh[c+d (x^2)] Erf[b x]dx  ⟶  (1/2) ∫(e^(c+d (x^2))) Erf[b x]dx-(1/2) ∫(e^(-c-d (x^2))) Erf[b x]dx

Program code:

Int[Sinh[c_.+d_.*x_^2]*Erf[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erf[b*x],x] - 1/2*Int[E^(-c-d*x^2)*Erf[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Int[Sinh[c_.+d_.*x_^2]*Erfc[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erfc[b*x],x] - 1/2*Int[E^(-c-d*x^2)*Erfc[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Int[Sinh[c_.+d_.*x_^2]*Erfi[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erfi[b*x],x] - 1/2*Int[E^(-c-d*x^2)*Erfi[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Int[Cosh[c_.+d_.*x_^2]*Erf[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erf[b*x],x] + 1/2*Int[E^(-c-d*x^2)*Erf[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Int[Cosh[c_.+d_.*x_^2]*Erfc[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erfc[b*x],x] + 1/2*Int[E^(-c-d*x^2)*Erfc[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Int[Cosh[c_.+d_.*x_^2]*Erfi[b_.*x_],x_Symbol] :=
  1/2*Int[E^(c+d*x^2)*Erfi[b*x],x] + 1/2*Int[E^(-c-d*x^2)*Erfi[b*x],x] /;
FreeQ[{b,c,d},x] && EqQ[d^2,b^4]

Rules for integrands involving special functions

1:  ∫F[f (a+b Log[c (((d+e x))^n)])]dx  when  F∈{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral}

Derivation: Integration by substitution

Rule: If  F∈{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral}, then

∫F[f (a+b Log[c (((d+e x))^n)])]dx  ⟶  (1/e) Subst[∫F[f (a+b Log[c (x^n)])]dx,x,d+e x]

Program code:

Int[F_[f_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])],x_Symbol] :=
  1/e*Subst[Int[F[f*(a+b*Log[c*x^n])],x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,n},x] && MemberQ[{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral},F]

2:  ∫(((g+h x))^m) F[f (a+b Log[c (((d+e x))^n)])]dx  when  e g-d h==0 ∧ F∈{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral}

Derivation: Integration by substitution

Basis: If  e g-d h==0, then (((g+h x))^m) F[d+e x]==(1/e) Subst[(((((g x)/d)))^m) F[x],x,d+e x] (∂_x)(d+e x)

Rule: If  e g-d h==0 ∧ F∈{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral}, then

∫(((g+h x))^m) F[f (a+b Log[c (((d+e x))^n)])]dx  ⟶  (1/e) Subst[∫(((((g x)/d)))^m) F[f (a+b Log[c (x^n)])]dx,x,d+e x]

Program code:

Int[(g_+h_.x_)^m_.*F_[f_.*(a_.+b_.*Log[c_.*(d_+e_.*x_)^n_.])],x_Symbol] :=
  1/e*Subst[Int[(g*x/d)^m*F[f*(a+b*Log[c*x^n])],x],x,d+e*x] /;
FreeQ[{a,b,c,d,e,f,g,m,n},x] && EqQ[e*f-d*g,0] && 
  MemberQ[{Erf,Erfc,Erfi,FresnelS,FresnelC,ExpIntegralEi,SinIntegral,CosIntegral,SinhIntegral,CoshIntegral},F]